***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 09, 2023                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BZX84C6V8-AU A K 
.param
+vc0 = 8.346e-11	vc1 = 1.086e-11		vc2 = 1.000		vc3 = 8.003e-15		vc4 = 2.857e0
+tc1 = 2.201e-2		tc2 = 1.501e-2		tc3 = 8.221e-3		tc4 = 2.301e-3
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 2.095e-15	   n = 1.054		  rs = 3.687e-1		    ikf = 2.596e-1
+ibv = 5e-3		 nbv = 1		  bv = 6.8
***** capacitance parameter *****
+cjo = 8.277e-11	   m = 3.910e-1		  vj = 8.621e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.148		 xti = 3
+trs1 = 1.535e-3	tbv1 = 4.602e-4		tikf = 2e-3
.ends BZX84C6V8-AU
*$
